/*
 * Copyright (C) 2014 Google Inc.
 *
 * Licensed under the Apache License, Version 2.0 (the "License"); you may not
 * use this file except in compliance with the License. You may obtain a copy of
 * the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
 * WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
 * License for the specific language governing permissions and limitations under
 * the License.
 */

rootProject.buildscript {
  String rosMavenPath = System.getenv("ROS_MAVEN_PATH")
  String rosMavenRepository = System.getenv("ROS_MAVEN_REPOSITORY")

  repositories {
    // TODO(damonkohler): Specify a single local ROS repo only. We shouldn't
    // need multiple repos.
    if (rosMavenPath != null) {
      rosMavenPath.tokenize(":").each { path ->
        maven {
          // We can't use uri() here because we aren't running inside something
          // that implements the Script interface.
          url "file:${path}"
        }
      }
    }
    maven {
      url "http://repository.springsource.com/maven/bundles/release"
    }
    maven {
      url "http://repository.springsource.com/maven/bundles/external"
    }
    if (rosMavenRepository != null) {
      maven {
        url rosMavenRepository
      }
    } else {
      maven {
        url "https://github.com/rosjava/rosjava_mvn_repo/raw/master"
      }
    }
    mavenCentral()
  }

  dependencies {
    classpath "org.ros.rosjava_bootstrap:gradle_plugins:0.2.0"
  }
}